[Xen-devel] [PATCH v2 10/27] x86/boot/64: Adapt assembly for PIE support

[Thomas Garnier <thgarnie@xxxxxxxxxx>]

Change the assembly code to use only relative references of symbols for the
kernel to be PIE compatible.

Early at boot, the kernel is mapped at a temporary address while preparing
the page table. To know the changes needed for the page table with KASLR,
the boot code calculate the difference between the expected address of the
kernel and the one chosen by KASLR. It does not work with PIE because all
symbols in code are relatives. Instead of getting the future relocated
virtual address, you will get the current temporary mapping. The solution
is using global variables that will be relocated as expected.

Position Independent Executable (PIE) support will allow to extended the
KASLR randomization range below the -2G memory limit.

Signed-off-by: Thomas Garnier <thgarnie@xxxxxxxxxx>
---
 arch/x86/kernel/head_64.S | 26 ++++++++++++++++++++------
 1 file changed, 20 insertions(+), 6 deletions(-)

diff --git a/arch/x86/kernel/head_64.S b/arch/x86/kernel/head_64.S
index 48385c1074a5..48652f3ec46a 100644
--- a/arch/x86/kernel/head_64.S
+++ b/arch/x86/kernel/head_64.S
@@ -89,8 +89,9 @@ startup_64:
        popq    %rsi
 
        /* Form the CR3 value being sure to include the CR3 modifier */
-       addq    $(early_top_pgt - __START_KERNEL_map), %rax
+       addq    _early_top_pgt_offset(%rip), %rax
        jmp 1f
+
 ENTRY(secondary_startup_64)
        UNWIND_HINT_EMPTY
        /*
@@ -119,7 +120,7 @@ ENTRY(secondary_startup_64)
        popq    %rsi
 
        /* Form the CR3 value being sure to include the CR3 modifier */
-       addq    $(init_top_pgt - __START_KERNEL_map), %rax
+       addq    _init_top_offset(%rip), %rax
 1:
 
        /* Enable PAE mode, PGE and LA57 */
@@ -137,7 +138,7 @@ ENTRY(secondary_startup_64)
        movq    %rax, %cr3
 
        /* Ensure I am executing from virtual addresses */
-       movq    $1f, %rax
+       movabs  $1f, %rax
        ANNOTATE_RETPOLINE_SAFE
        jmp     *%rax
 1:
@@ -234,11 +235,12 @@ ENTRY(secondary_startup_64)
         *      REX.W + FF /5 JMP m16:64 Jump far, absolute indirect,
         *              address given in m16:64.
         */
-       pushq   $.Lafter_lret   # put return address on stack for unwinder
+       leaq    .Lafter_lret(%rip), %rax
+       pushq   %rax            # put return address on stack for unwinder
        xorq    %rbp, %rbp      # clear frame pointer
-       movq    initial_code(%rip), %rax
+       leaq    initial_code(%rip), %rax
        pushq   $__KERNEL_CS    # set correct cs
-       pushq   %rax            # target address in negative space
+       pushq   (%rax)          # target address in negative space
        lretq
 .Lafter_lret:
 END(secondary_startup_64)
@@ -342,6 +344,18 @@ END(early_idt_handler_common)
 GLOBAL(early_recursion_flag)
        .long 0
 
+       /*
+        * Position Independent Code takes only relative references in code
+        * meaning a global variable address is relative to RIP and not its
+        * future virtual address. Global variables can be used instead as they
+        * are still relocated on the expected kernel mapping address.
+        */
+       .align 8
+_early_top_pgt_offset:
+       .quad early_top_pgt - __START_KERNEL_map
+_init_top_offset:
+       .quad init_top_pgt - __START_KERNEL_map
+
 #define NEXT_PAGE(name) \
        .balign PAGE_SIZE; \
 GLOBAL(name)
-- 
2.16.2.660.g709887971b-goog


_______________________________________________
Xen-devel mailing list
Xen-devel@xxxxxxxxxxxxxxxxxxxx
https://lists.xenproject.org/mailman/listinfo/xen-devel